LETTERS

Ada 95

In October 1993, DDJ featured comparisons of various OOP languages. You did a great service by leveling the playing field and demonstrating how a specific problem could be coded and solved in each of the selected languages.

I realize that at the time of your article, the updated Ada standard was not yet available. However, as of February 15, 1995, the Ada 95 language has become an official ISO, ANSI, and FIPS standard. Given that Ada 95 may in fact be the first internationally standardized OOPL, I thought I would contribute an Ada 95 solution to the original DDJ challenge.

Example 1 uses a heterogeneous, linked list of objects that can be dynamically dispatched (through the polymorphic Print routine) depending on the derivation of the abstract type called Item.

The freely available GNU GNAT Ada 95 compiler (available from ftp:cs.nyu.edu in the /pub/gnat directory) was used to compile this code. Besides the OO features, Ada 95 also introduces improvements in exception handling, generic programming, memory management, tasking, and programming-in-the-large.

Paul Pukite

Minneapolis, Minnesota

Example 1: Ada 95.
package PList is  -- A printable list of heterogeneous items
   type Item is abstract tagged null record;
   procedure Print (This : Item) is abstract;
   type Element is access Item'Class;
   type List is private;
   function New_List return List;
   procedure Append (To_List   : in out List;
                     This_Item : in     Element);
   procedure Print (This : in List);
private
   type Node;
   type Pointer is access Node;
   type Node is record
      Contents : Element;
      Next     : Pointer;
   end record;
   type List is record
      First, Last : Pointer;
   end record;
end PList;
package body PList is  -- The implementation of printable list
   function New_List return List is
   begin
      return (List'(First => null, Last => null));
   end New_List;
   procedure Append (To_List   : in out List;
                     This_Item : in     Element) is
      New_Node : Pointer := new Node'(Contents => This_Item, Next => null);
   begin
      if To_List.First = null then
         To_List.First := New_Node;
         To_List.Last := New_Node;
      else
         To_List.Last.Next := New_Node;
         To_List.Last := New_Node;
      end if;
   end Append;
   procedure Print (This : in List) is
      Current : Pointer := This.First;
   begin
      while Current /= null loop
         Print (Current.Contents.all);
         Current := Current.Next;
      end loop;
   end Print;
end PList;
with PList, Text_IO;
procedure Test is  -- The main program
   Object_List : PList.List := PList.New_List;
   type Number is new PList.Item with record
      Value : Integer := 0;
   end record;
   procedure Print (This : Number);
   type Point is new PList.Item with record
      X, Y : Integer := 0;
   end record;
   procedure Print (This : Point);
   N1 : aliased Number := (Value => 10);
   N2 : aliased Number := (Value => 20);
   P1 : aliased Point  := (X => 2, Y => 3);
   P2 : aliased Point  := (X => 4, Y => 5);
   procedure Print (This : Number) is
   begin
      Text_IO.Put_Line ("Num:" & Integer'Image(This.Value));
   end Print;
   procedure Print (This : Point) is
   begin
      Text_IO.Put_Line ("Pt:" & Integer'Image(This.X) & Integer'Image(This.Y));
   end Print;
begin  -- Add Number and Point items to list and then print
   PList.Append (To_List => Object_List, This_Item => N1'Access); -- by name
   PList.Append (Object_List, N2'Access); -- or by position
   PList.Append (Object_List, P1'Access);
   PList.Append (Object_List, P2'Access);
   PList.Print (Object_List);
end Test;

LETTERS

Ada 95

Stepanov and STL

Image Authentication

Network Options

Setting the Revolution Record Straight

Flash File Systems

Running Light